all things L337

Few handy code Snippets for when using AS3 & Video.

This can be used with FLVPlayBack Component (just remove the vars/addChilds etc):

import fl.video.*;
var myVideo:FLVPlayback = new FLVPlayback();
myVideo.source = "video.flv";
myVideo.skin = "SkinOverPlayStopSeekFullVol.swf";
myVideo.addEventListener(VideoEvent.COMPLETE, completePlay);
function completePlay(e:VideoEvent):void {
myVideo.alpha=0.2;
}
addChild(myVideo);

Net Stream Version:

var nc:NetConnection = new NetConnection();
nc.connect(null);

var ns:NetStream=new NetStream(nc);
ns.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler);
ns.play("video.flv");
function asyncErrorHandler(event:AsyncErrorEvent):void {
	// ignore error
}

var vid:Video = new Video();
vid.attachNetStream(ns);
addChild(vid);

pauseBtn.addEventListener(MouseEvent.CLICK, pauseHandler);
playBtn.addEventListener(MouseEvent.CLICK, playHandler);
stopBtn.addEventListener(MouseEvent.CLICK, stopHandler);
togglePauseBtn.addEventListener(MouseEvent.CLICK, togglePauseHandler);

function pauseHandler(event:MouseEvent):void {
	ns.pause();
}
function playHandler(event:MouseEvent):void {
	ns.resume();
}
function stopHandler(event:MouseEvent):void {
	// Pause the stream and move the playhead back to
	// the beginning of the stream.
	ns.pause();
	ns.seek(0);
}
function togglePauseHandler(event:MouseEvent):void {
	ns.togglePause();
}

ns.addEventListener(NetStatusEvent.NET_STATUS, statusHandler);
function statusHandler(event:NetStatusEvent):void {

	trace(event.info.code);
	/*
	NetStream.Play.Start
	NetStream.Buffer.Empty
	NetStream.Buffer.Full
	NetStream.Buffer.Empty
	NetStream.Buffer.Full
	NetStream.Buffer.Empty
	NetStream.Buffer.Full
	NetStream.Buffer.Flush
	NetStream.Play.Stop
	NetStream.Buffer.Empty
	NetStream.Buffer.Flush
	*/
	switch (event.info.code) {
		case "NetStream.Play.Start" :
			trace("Start [" + ns.time.toFixed(3) + " seconds]");
			break;
		case "NetStream.Play.Stop" :
			trace("Stop [" + ns.time.toFixed(3) + " seconds]");
			break;
	}
}